$ontext
$model:belarus
	
$commodities:
	PD(g)$ng(g)	!	Domestic price
	PM(i)$m0(i)	!	Import price
	PX(g)$x0(g)	!	Export price
	PT(mrg)		!	Margins
	P(i,g)$id0(i,g)	!	Intermediate demand
	PKS(g)$ssk0(g)	!	Sector specific capital rental rate
	PK		!	Mobile capital rental rate
	PL		!	Wage rate
	PFX		!	Foreign exchange
	PC(h)		!	Price of a unit of utility

$sectors:
	Y(g)$ng(g)	!	Production and final demand
	ID(i,g)$id0(i,g)!	Intermediate demand	
	TT(mrg)		!	Trade and transport margin
	M(i)$m0(i)	!	Import
	X(i)$x0(i)	!	Export
	C(h)$c0(h)	!	Household consumption

$consumers:
	GOVT		!	Government
	HH(h)		!	Households (10 deciles)

$auxiliary:
	TAU_TAX		!	Multiplier on household electricity taxes (subsidy)
	TAU_LUMP	!	Multiplier on lump sum transfers to government
	HHTAU_LUMP(h)	!	Optimal welfare neutreul household payments (duel)
	HHQ_LUMP	!	Multiplier (primal)
	HHTAU_TAX(h)	!	Optimal welfare neutral household tax subsidies
	HHQ_TAX		!	Multiplier (primal)

$prod:Y(ng)   s:0  t:etrans va(s):esubva cen(va):esubcen eng(cen):esubeng cap(cen):0
	o:PX(ng)	q:x0(ng)		a:GOVT	t:ty(ng)
	o:PD(ng)	q:d0(ng)		a:GOVT	t:ty(ng)
	i:P(nengy,ng)	q:id0(nengy,ng)		a:GOVT  t:t0(nengy,ng)	p:(1 + t0(nengy,ng))
	i:PL		q:ld0(ng)	va:
	i:PK		q:kd0(ng)	cap:
	i:PKS(ng)	q:ssk0(ng)	cap:
	i:P(engy,ng)	q:id0(engy,ng)	eng:	a:GOVT t:(phi(engy,ng) * t0(engy,ng))	p:(1 + t0(engy,ng))

$report:
	v:LD(g)$ld0(g)		i:PL		prod:Y(g)
	v:MKD(g)$kd0(g)		i:PK		prod:Y(g)
	v:SKD(g)$ssk0(g)	i:PKS(g)	prod:Y(g)
	v:IMI(i,g)$id0(i,g)	i:P(i,g)	prod:Y(g)
	v:DO(g)$d0(g)		i:PD(g)		prod:Y(g)
	v:XO(g)$x0(g)		i:PX(g)		prod:Y(g)
	
$prod:ID(i,g)$id0(i,g)    s:0  dm:esubarm
	o:P(i,g)	q:id0(i,g)
	i:PT(mrg)	q:tt0(mrg,i,g)
	i:PD(i)		q:dd0(i,g)	dm:
	i:PM(i)		q:md0(i,g)	dm:

$prod:TT(mrg)
	o:PT(mrg)	q:(dt0(mrg)+mt0(mrg))
	i:PD(mrg)	q:dt0(mrg)
	i:PM(mrg)	q:mt0(mrg)

$prod:X(i)$x0(i)
	o:PFX		q:(xfob0(i)*pwx)	
	i:PX(i)		q:x0(i)
	i:PM(i)		q:md0(i,"exp")
	i:PT(mrg)	q:tt0(mrg,i,"exp")

$prod:M(i)$m0(i)
	o:PM(i)		q:m0(i)
	i:PFX		q:(m0(i)*pwm)

$prod:C(h)$c0(h)    s:esubdem
	o:PC(h)			q:c0(h)
	i:P(nel,"hh")		q:id0_h(nel,h)		a:GOVT	t:t0(nel,"hh")	p:(1+t0(nel,"hh"))
	i:P("util","hh")	q:id0_h("util",h)	a:GOVT  n:HHTAU_TAX(h)	m:t0("util","hh")	p:(1+t0("util","hh"))

$report:
	v:HED(h)$id0_h("util",h)	i:P("util","hh")	prod:C(h)

$demand:HH(h)
	d:PC(h)		q:c0(h)
	e:PD(i)		q:(-xdd0_h(h,i)-tdd0_h(h,i))
	e:PM(i)		q:(-xmd0_h(h,i)-tmd0_h(h,i))
	e:PT(mrg)	q:(-xtt0_h(h,mrg)-ttt0_h(h,mrg))
	e:PL		q:ls0_h(h)
	e:PK#(i)	q:kd0_h(h,i)
	e:PKS(i)	q:ssk0_h(h,i)
	e:PC(h)		q:trn0_h(h)	r:HHTAU_LUMP(h)

$report:
	v:W(h)		w:HH(h)	
	
$demand:GOVT s:0
	d:PD(pub)	q:d0(pub)
	e:PC(h)		q:(-trn0_h(h))	r:HHTAU_LUMP(h)
	e:PFX		q:bopdef
	e:PD(i)		q:tdd0(i)
	e:PM(i)		q:tmd0(i)
	e:PT(mrg)	q:ttt0(mrg)
	e:PFX		q:(-1)		r:HHQ_LUMP
	e:PFX		q:(-1)		r:HHQ_TAX

*	Fix the government budget:

$constraint:TAU_TAX
	GOVT =e= sum(pub, PD(pub) * d0(pub));

$constraint:HHTAU_TAX(h)
	HH(h) =e= PC(h)*ra0(h);

$constraint:HHQ_TAX
	TAU_TAX * t0("util","hh") * sum(h, id0_h("util",h)*C(h) * (P("util","hh")/PC(h))**esubdem) =e= sum(h, HHTAU_TAX(h) * t0("util","hh") * id0_h("util",h) * C(h) * (P("util","hh")/PC(h))**esubdem);

$constraint:TAU_LUMP
	GOVT =e= sum(pub, PD(pub) * d0(pub));

$constraint:HHTAU_LUMP(h)
	HH(h) =e= PC(h)*ra0(h);

$constraint:HHQ_LUMP
	TAU_LUMP * sum(h, PC(h) * trn0_h(h)) =e= sum(h, HHTAU_LUMP(h) * PC(h) * trn0_h(h));

$offtext